「ｉ」家の趣向

// Wake On Lan リピーター
// http://yutakalife.net/article/303195021.html
// 販売などの商用利用はご遠慮ください
// Copyright love4nature All Rights Reserved.

#include <SPI.h>
#include <Ethernet.h>
#include <EthernetUdp.h>


// イーサネットの設定
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };    // Arduino のMAC address
IPAddress ip(192, 168, 0, 200);    // Arduino のIP address
unsigned int localPort = 9;      // Arduino の受信ポート

IPAddress targetIp(192, 168, 0, 255);    // ターゲットのブロードキャストアドレスを設定
unsigned int targetPort = 8000;    // ターゲットのポート番号を設定

// パケットサイズの最大値を設定
#define MAX_SIZE 192

byte packetBuffer[MAX_SIZE]; // マジックパケット用のパケットバッファ

// An EthernetUDP instance to let us send and receive packets over UDP
EthernetUDP Udp;

void setup() {
  // start the Ethernet and UDP:
  Ethernet.begin(mac,ip);
  Udp.begin(localPort);

  Serial.begin(115200);
  Serial.print("Start ");
}

void loop() {
  // if there's data available, read a packet
  int packetSize = Udp.parsePacket();
  if(packetSize)
  {
    Serial.print("Received packet of size ");
    Serial.println(packetSize);
    Serial.print("From ");
    IPAddress remote = Udp.remoteIP();
    for (int i =0; i < 4; i++)
    {
      Serial.print(remote[i], DEC);
      if (i < 3)
      {
        Serial.print(".");
      }
    }
    Serial.print(", port ");
    Serial.println(Udp.remotePort());

    // read the packet into packetBufffer
    Udp.read(packetBuffer,MAX_SIZE);
    Serial.println("Contents:");
    for(int j=0; j<min(MAX_SIZE,abs(packetSize)); j++) {
        Serial.print(packetBuffer[j],HEX);
        Serial.print(" ");
    }
    Serial.println("");

    // 受信したマジックパケットをリピート送信する
    Udp.beginPacket(targetIp, targetPort);
    Udp.write(packetBuffer,min(MAX_SIZE,abs(packetSize)));
    Udp.endPacket();
  }
  delay(10);
}